Правильный экспорт из Excel в CSV - [VM1] Импорт-экспорт данных

Sub csvDelim()
' Для создания csv-файла заданного формата
' Макрос добавлен 2011-02-08
' Создает csv-файл из эксельного.
' Просит указать диапазон заголовков. Необходимо указывать именно заголовки!
' Определяет диапазон строк по первому столбцу
' Спрашивает маску файла
' Можно задать разделитель и ограничитель полей
Dim i As Long, j As Long
Dim PathForFile As String
Dim NameForSave As String
Dim tempstr As String
Dim Rn As Range
Dim Delim1 As String
Dim Delim2 As String
Dim Val
On Error Resume Next
PathForFile = "C:\Готово\"
MsgBox "На вашем локальном диске будет создана папка ""Готово""", vbOKOnly, "Создание папки"
MkDir PathForFile
If Err.Number <> 75 And Err.Number <> 0 Then GoTo Ext
Err.Clear
On Error GoTo Ext
NameForSave = InputBox("Введите маску файла", "Ввод", ActiveWorkbook.Name)
Delim1 = CStr(InputBox("Введите разделитель полей", "Ввод", ";"))
Delim2 = CStr(InputBox("Введите ограничитель полей", "Ввод", """"))
Randomize
NameForSave = NameForSave & "_" & CStr(Date)
Set Rn = Application.InputBox("Выделите, пожалуйста, все ЗАГОЛОВКИ нужных столбцов.", , , , , , , 8)
i = 1
While Len(Rn.Cells(1).Offset(i).Value) > 0
    i = i + 1
Wend
If i = 1 Then Exit Sub
Val = Rn.Offset(1).Resize(i).Value
On Error Resume Next
Kill PathForFile & "\" & NameForSave & ".csv"
Err.Clear
On Error GoTo Ext
Open PathForFile & "\" & NameForSave & ".csv" For Output As #1
For i = 1 To UBound(Val, 1) - 1
    tempstr = Delim2 & CStr(Val(i, 1)) & Delim2
    For j = 2 To UBound(Val, 2)
        tempstr = tempstr & Delim1 & Delim2 & CStr(Val(i, j)) & Delim2
    Next j
    Print #1, tempstr
Next i
Close #1
Exit Sub
Ext:
MsgBox "Извините, ошибка!" & Err.Number & " " & Err.Description, vbOKOnly, "Упс!"
End Sub